跳到主要內容

 自 109 / 2 /25 起啟用

物聯網 / 數據上傳 / 溫濕+PM2.5+CO2

※ 上傳程式前,需先將 PM2.5 感測器轉接板拔掉,以免程式上傳失敗 
 
#include "ESP8266WiFi.h"  //匯入WiFi程式庫
#include "SSD1306.h" //匯入OLED程式庫
#include "PMS.h"  //匯入PM2.5程式庫
#include "DHTesp.h"  //匯入DHT程式庫
#include "SoftwareSerial.h" //匯入自訂軟體序列埠程式庫
#define SOFT_TX D5  //自訂軟體串列埠接腳TX
#define SOFT_RX D6  //自訂軟體串列埠接腳RX
SSD1306  display(0x3C, D2, D1);    //宣告使用OLED螢幕物件(位址,SDA,SCL)==SDA>D2,SCL>D1
PMS pms(Serial);
PMS::DATA data;
DHTesp dht; //宣告dht物件
int PM25_value=0;  //宣告一個整數變數PM25_value
float humidity=0.0; //宣告一個資料型態為float的全域變數humidity
float temperature=0.0;  //宣告一個資料型態為float的全域變數temperature
unsigned int CO2_ppm;  //定義儲存CO2濃度的變數CO2_ppm
SoftwareSerial mySerial(SOFT_RX, SOFT_TX); //宣告使用軟體序列埠RX, TX
long previousTime = 0;          // 用來保存前一次狀態的時間
long interval = 2000;           // 讀取間隔時間,單位為毫秒(miliseconds)
const char *API_KEY = "XF8EKI32E9BFCZQ0";  //ThingSpeak取得的apiKey,請更換為各組之apikey
const char *HOST = "api.thingspeak.com";  //定義連線至thingspeak網站的IP位址
const char* MY_SSID = "TCGS-IOT";    //無線基地台SSID名稱
const char* MY_PWD = "22205108";     //無線基地台密碼
void setup()
{
  Serial.begin(9600);
  mySerial.begin(9600); //使用軟體序列埠傳遞CO2數據
  display.init(); //螢幕初始化
  display.flipScreenVertically();  //螢幕垂直翻轉
  display.setFont(ArialMT_Plain_16);    //使用16字體
  display.setTextAlignment(TEXT_ALIGN_LEFT);    //靠左對齊
  dht.setup(D3, DHTesp::DHT11);   // 設定DHT的接腳位置及DHT的型號DHT11或DHT22
  connectWifi();  //呼叫網路連線函數
}
void loop()
{
  unsigned long currentTime = millis();
  if (pms.read(data)){
      PM25_value=data.PM_AE_UG_2_5;   //將讀取到的PM2.5數值存入PM25_value
    }
    
  if(currentTime - previousTime > interval) {
    humidity = dht.getHumidity(); //讀取濕度值儲存於humidity變數內
    temperature = dht.getTemperature(); //讀取溫度值儲存於temperature變數內
    //讀取CO2感測器數據開始
    unsigned char CO2_Read[]={0x42,0x4d,0xe3,0x00,0x00,0x01,0x72};
    unsigned char CO2_val[12];
    mySerial.write(CO2_Read,7);   // 送出 7 個 bytes 位元組之指令至自訂軟體序列埠 mySerial
    delay(1000);
    while(mySerial.available()){
       mySerial.readBytes(CO2_val,12);   // 讀取回應之 12 個 bytes 位元組的資料
    }
    CO2_ppm = CO2_val[4]*256+CO2_val[5];  //將CO2的數值存入變數CO2_ppm,CO2的濃度在第5個(高位元)、第6個(低位元)byte
    //讀取CO2感測器數據結束     
    send_Data();   //每2秒呼叫一次上傳資料函數,可建議修改為5秒或10秒
    previousTime = currentTime;  // 記錄更新時間
 
  }
    display.clear();  //清除螢幕
    display.drawString(0, 0, "T:"+String(temperature)+"*C"); //x=0,y=0位置顯示溫度的值
    display.drawString(0, 16, "H:"+String(humidity)+"%"); //x=0,y=16位置顯示濕度的值
    display.drawString(0, 32, "PM2.5="+String(PM25_value)); //x=0,y=32位置顯示PM25_value數值
    display.drawString(0, 48, "CO2:"+String(CO2_ppm)+"ppm"); //x=0,y=48位置顯示CO2的值
    display.display();  //OLED螢幕顯示畫面      
}
void connectWifi()  //網路連線函數
{
  WiFi.begin(MY_SSID, MY_PWD);   //連線至MY_SSID無線基地台,MY_PWD為連線密碼
  while (WiFi.status() != WL_CONNECTED) { 
  delay(1000);
  display.clear();  //清除螢幕
  display.drawString(0, 0, "connect Wifi...");  //將connect Wifi...字串放入暫存區
  display.display();//螢幕顯示畫面
  }  
}
 
void send_Data()
{  
   WiFiClient client;  // 設定 ESP8266 作為 Client 端
 
  if ( !client.connect( HOST, 80 ) ) {
    Serial.println("connection failed");
    return;
  } else {
      String URL = "GET /update?key=";   // 以GET方式上傳資料到 ThingSpeak伺服器
             URL += API_KEY;
             URL += "&field1=";     //field1上傳溫度數據
             URL += temperature;
             URL += "&field2=";     //field2上傳濕度數據
             URL += humidity; 
             URL += "&field3=";     //field3上傳PM2.5數據
             URL += PM25_value;
             URL += "&field4=";     //field4上傳CO2數據
             URL += CO2_ppm;                                     
             URL += "  HTTP/1.1\n";
    
    client.print( URL + "Host: " + HOST + "\r\n" +
                  "Connection: close\r\n\r\n" );
  }
}

消息公佈欄

時間類別單位標題發佈點閱
跳至網頁頂部