前罝作業：在 LINE 官方帳號中建立 Messaging API Channel，用來發送訊息給使用者。
[發送 HTTP POST 請至 Line Messaging API ]
│
│ (POST JSON: push message)
▼
[LINE Messaging API Channel（官方帳號）]
│
│ (發送訊息)
▼
[你的 LINE 帳號]
建立 LINE Bot.：建立 Provider → 在 Provider 底下建立 LINE 官方帳號 → 在官方帳號底下建立 Messaging API Channel
登入 LINE Developers 網頁，Create a new Provider → Create a Messaging API channel
跳轉至 Create a LINE Official Account 網頁，建立 LINE 官方帳號，帳號建立後，按【⚙️ 設定】進入設定頁面。
回至 LINE Developers 網頁，設定剛剛建立好的 Messaging API channel。
－於【Basic settings】頁面，取得 Your user ID。
－於【Messaging API】頁面，於【Channel access token】按下 Issue 按鈕，取得存取令牌。
※ 上傳程式前，需先將 PM2.5 感測器轉接板拔掉，以免程式上傳失敗 ※
#include "ESP8266WiFi.h" //匯入WiFi程式庫
#include "WiFiClientSecure.h" //匯入安全連線程式庫 (用於 HTTPS/SSL 加密通訊)
#include "SSD1306.h" //匯入OLED程式庫
#include "PMS.h" //匯入PM2.5程式庫
SSD1306 display(0x3C, D2, D1); //(位址,SDA,SCL）==SDA>D2,SCL>D1
long previousTime = 0; // 用來保存前一次狀態的時間
long interval = 2000; // 讀取間隔時間，單位為毫秒(miliseconds)
PMS pms(Serial);
PMS::DATA data;
int PM25_value=0; //宣告一個整數變數PM25_value
const char* MY_SSID = "TCGS-IOT"; //無線基地台SSID名稱
const char* MY_PWD = "22205108"; //無線基地台密碼
const char* host = "api.line.me";
const int httpsPort = 443;
const char* LINE_TOKEN = "你的 LINE Channel Access Token"; // 更改為你的 Channel access token（長效）
const char* userID = "你的 LINE User ID"; // 更改為你的 LINE 使用者 ID
void setup()
{
Serial.begin(9600);
display.init(); //螢幕初始化
display.flipScreenVertically(); //螢幕垂直翻轉
display.setFont(ArialMT_Plain_16); //16字體
display.setTextAlignment(TEXT_ALIGN_LEFT); //靠左對齊
connectWifi(); //呼叫網路連線函數
}
void loop()
{
unsigned long currentTime = millis(); //將當前的時間存入變數currentTime
if (pms.read(data)){
PM25_value=data.PM_AE_UG_2_5; //將讀取到的PM2.5數值存入PM25_value
}
if(currentTime - previousTime > interval) { //如果當前時間扣除前一次保留時間超過間隔時間(interval)就進入執行程式
String PM25="【PM2.5】\\nPM2.5: "+String(PM25_value)+"ug/m3"; //設定PM2.5字串，其為 JSON 格式需 escape \\n 換行
sendLineMessage(PM25); // 呼叫自訂函式 sendLineMessage() 傳送 Line 訊息
previousTime = currentTime; // 離開if時更新時間
}
display.clear(); //清除螢幕
display.drawString(0, 0, "Group 1"); //x=64,y=0位置顯示Group 1
display.drawString(0, 16, "PM2.5:"+String(PM25_value)+"ug/m3"); //x=0,y=16位置顯示PM2.5的值
display.display();//螢幕顯示畫面
}
void connectWifi() //網路連線函數
{
WiFi.begin(MY_SSID, MY_PWD); //連線至MY_SSID無線基地台，MY_PWD為連線密碼
while (WiFi.status() != WL_CONNECTED) {
delay(1000);
display.clear();
display.drawString(0, 0, "connect Wifi...");
display.display();//螢幕顯示畫面
}
}
void sendLineMessage(String message) {
WiFiClientSecure client;
client.setInsecure(); // 忽略 SSL 憑證驗證
if (!client.connect(host, httpsPort)) {
Serial.println("❌ 無法連線到 LINE API");
return;
}
String url = "/v2/bot/message/push";
// 準備 HTTP POST 的內容 (要傳的訊息 JSON 格式)
String payload =
"{\"to\":\"" + String(userID) + "\","
"\"messages\":[{\"type\":\"text\",\"text\":\"" + message + "\"}]}";
// 組成 HTTP POST 請求 (含標頭 + JSON 內容)
String headers =
String("POST ") + url + " HTTP/1.1\r\n" +
"Host: " + host + "\r\n" +
"Authorization: Bearer " + LINE_TOKEN + "\r\n" +
"Content-Type: application/json\r\n" +
"Content-Length: " + payload.length() + "\r\n\r\n" +
payload;
client.print(headers); // 發送 HTTP POST 請求送到 LINE API
}
執行結果：
