HC-SR04 超音波感測器提供 2cm 至 400cm 的非接觸式距離測量功能，測距精度可達 3mm。每個 HC-SR04 模塊包括一個超聲波發射器（Transport），一個接收器（Reveive）和一個控制電路。在 HC-SR04 上只需要四個接腳：VCC（電源），Trig（觸發端），Echo（接收端）和 GND（接地）。
HC-SR04 工作原理
（1）採用 Trig 腳觸發測距，模組的 Trig 腳高電位至少 10μs。
（2）當 Trig 腳變成低電位時，模組自動發送 8 個 40 kHz 的方波，並且檢測是否有信號返回。
（3）如有信號返回，模組的 Echo 腳輸出高電位。Echo 腳高電位持續的這段時間，就是超音波從發射到返回的時間。
超音波在空氣中的傳播速度：音速 V = 331 m/s + 0.6 * T（T 為空氣的攝式溫度)，空氣溫度愈高，傳播速度音速就愈快。
常溫下音速每秒約 340 公尺，量測距離 =（Echo 腳高電位持續時間 x 音速（340 m/s））/ 2。
接線方式
● Vcc：接電源正極
● Trig：接任意 Digital Pin（程式範例接 D5）
● Echo：接位意 Digital Pin（程式範例接 D6）
● Gnd：接電源負極
#include "SSD1306.h" //匯入OLED程式庫
SSD1306 display(0x3C, D2, D1); //宣告使用OLED螢幕物件(位址,SDA,SCL）==SDA>D2,SCL>D1
#define trigPin D5 // 設定 Trig 的接腳位置(D5 or 14）
#define echoPin D6 // 設定 Echo 的接腳位置(D6 or 12）
long duration, distance;
long previousTime = 0; // 用來保存前一次狀態的時間
long interval = 500; // 讀取間隔時間，單位為毫秒(miliseconds)
void setup() {
display.init(); //螢幕初始化
display.flipScreenVertically(); //螢幕垂直翻轉
display.setFont(ArialMT_Plain_16); //使用16字體
display.setTextAlignment(TEXT_ALIGN_LEFT); //靠左對齊
pinMode(trigPin, OUTPUT); // 設定 trigPin 為輸出模式
pinMode(echoPin, INPUT); // 設定 tchoPin 為輸入模式
}
void loop() {
unsigned long currentTime = millis(); //將當前的時間存入變數currentTime
if (currentTime - previousTime > interval) { //如果當前時間扣除前一次保留時間超過間隔時間(interval)就進入執行程式
digitalWrite(trigPin, LOW);
delayMicroseconds(2);
digitalWrite(trigPin, HIGH); // Trig 觸發測距，給至少 10us 的高電位信號
delayMicroseconds(10);
digitalWrite(trigPin, LOW);
duration = pulseIn(echoPin, HIGH); // 讀取 Echo 腳高電位的持續時間，即超音波從發射到返回的時間
distance = duration*0.034/2; // 距離=(高電位時間*音速(340m/s))/2;
previousTime = currentTime; // 離開if時更新時間
}
display.clear(); //清除螢幕
display.drawString(0, 0, "distance : "+String(distance)+" cm"); //x=0,y=0 位置顯示距離的值
display.display();//螢幕顯示畫面
}
►
