#include "ESP8266WiFi.h" //匯入WiFi程式庫
#include "WiFiClientSecure.h" //匯入安全連線程式度（用於 HTTPS/SSL 加密通訊）
#include "SSD1306.h"
SSD1306 display(0x3C, D2, D1); //(位址,SDA,SCL）==SDA>D2,SCL>D1
unsigned long previousTime = 0; // 用來保存前一次狀態的時間
unsigned long interval = 500; // 讀取間隔時間，單位為毫秒(miliseconds)
float voice_value=0; //宣告一個資料型態為float的全域變數voice_value
bool alertSent = false; //記錄是否已發送過 Line 通知
const char *API_KEY = "XRCOLW1LYAHVABX1"; //ThingSpeak取得的apiKey，請更換為各組之apikey
const char *HOST = "api.thingspeak.com"; //定義連線至thingspeak網站的IP位址
const char* MY_SSID = "TCGS-IOT"; //無線基地台SSID名稱
const char* MY_PWD = "22205108"; //無線基地台密碼
const char* host = "api.line.me";
const int httpsPort = 443;
const char* LINE_TOKEN = "你的 LINE Channel Access Token"; // 更改為你的 Channel access token（長效）
const char* userID = "你的 LINE User ID"; // 更改為你的 LINE 使用者 ID
void setup()
{
Serial.begin(115200); //啟動序列埠監控，供除錯訊息輸出使用
display.init(); //螢幕初始化
display.flipScreenVertically(); //螢幕垂直翻轉
display.setFont(ArialMT_Plain_16); //16字體
display.setTextAlignment(TEXT_ALIGN_LEFT);//置左對齊
connectWifi(); //呼叫網路連線函數
}
void loop()
{
unsigned long currentTime = millis(); //將當前的時間存入變數currentTime
if(currentTime - previousTime > interval) { //如果當前時間扣除前一次保留時間超過間隔時間(interval)就進入執行程式
int i=analogRead(A0);
voice_value=i*(3.3/1024)*50;
previousTime = currentTime; // 離開if時更新時間
send_Data(); //呼叫上傳資料函數
if (voice_value>90 && !alertSent){
String message = "聲音:"+String(voice_value)+"dB\\n音量超標警報";
sendLineMessage(message);
alertSent = true;
}
else if ( voice_value <= 90) {
alertSent = false;
}
display.clear(); //清除螢幕
display.drawString(0, 0, "Group 1"); //x=0,y=0位置顯示Group 1
display.drawString(0, 16, "voice:"+String(voice_value)); //x=0,y=16位置顯示聲音感測器類比值
display.display();//螢幕顯示畫面
}
}
void connectWifi() //網路連線函數
{
WiFi.begin(MY_SSID, MY_PWD); //連線至MY_SSID無線基地台，MY_PWD為連線密碼
while (WiFi.status() != WL_CONNECTED) {
delay(1000);
display.clear(); //清除螢幕
display.drawString(0, 0, "connect Wifi..."); //將connect Wifi...字串放入暫存區
display.display();//螢幕顯示畫面
}
}
void send_Data()
{
WiFiClient client; // 設定 ESP8266 作為 Client 端
if ( !client.connect( HOST, 80 ) ) {
Serial.println("connection failed");
return;
} else {
String URL = "GET /update?key="; // 以GET方式上傳資料到 ThingSpeak伺服器
URL += API_KEY;
URL += "&field1="; //field1上傳聲音感測器分貝數據
URL += voice_value;
URL += " HTTP/1.1\r\n";
client.print( URL + "Host: " + HOST + "\r\n" +
"Connection: close\r\n\r\n" );
}
}
void sendLineMessage(String message) {
WiFiClientSecure client;
client.setInsecure(); // 忽略 SSL 憑證驗證
if (!client.connect(host, httpsPort)) {
Serial.println("❌ 無法連線到 LINE API");
return;
}
String url = "/v2/bot/message/push";
// 準備 HTTP POST 的內容 (要傳的訊息 JSON 格式)
String payload =
"{\"to\":\"" + String(userID) + "\","
"\"messages\":[{\"type\":\"text\",\"text\":\"" + message + "\"}]}";
// 組成 HTTP POST 請求 (含標頭 + JSON 內容)
String headers =
String("POST ") + url + " HTTP/1.1\r\n" +
"Host: " + host + "\r\n" +
"Authorization: Bearer " + LINE_TOKEN + "\r\n" +
"Content-Type: application/json\r\n" +
"Content-Length: " + payload.length() + "\r\n\r\n" +
payload;
client.print(headers); // 發送 HTTP POST 請求送到 LINE API
}
