MQ-2 氣體傳感器所使用的氣敏材料是在清潔空氣中電導率較低的二氧化錫（SnO2），當傳感器所處環境中存在可燃氣體時，傳感器的電導率隨空氣中可燃氣體濃度的增加而增大，當煙霧的濃度越大，導電率越大，輸出電阻越低，則輸出的模擬信號就越大，常用於家庭和工廠的氣體泄漏監測裝置，適用於液化氣 (LPG)、丁烷 (i-butane)、丙烷 (propane)、甲烷 (methane)、酒精 (alcohol)、氫氣 (Hydrogen)、煙霧 (smoke) 等氣體的偵測。
功能介紹
接上 5V 電源，POWER LED 電源指示燈亮。
DO 數位訊號輸出：檢測可燃氣體濃渡是否高於設定值（高於設定值時輸出 LOW），亦可直接驅動繼電器模組做相關電器啟動。
在無敏感氣體影響或者氣體濃度未超過設定閾值時，DO 輸出為高電位，DOUT LED 指示燈滅，
當氣體影響超過設定閾值時，DO 輸出為低電位，DOUT LED 指示燈亮。
透過調節控制板上藍色電位器選擇對應閾值，調整 DO 偵測可燃氣/煙霧的靈敏度。
AO 類比訊號輸出：檢測可燃氣/煙霧濃度高低（濃度越高、數值越大），nodeMCU 的 A/D 轉換器與 Arduino 的 A/D 轉換器解析度為 10 位元，故可呈現的數字範圍為 0 ~ 1023，可燃氣/煙霧濃度會跟數值成正比，濃度越高數值越大。
接線方式
● VCC：接電源正極 5V
● GND：接電源負極
● DO：數位訊號輸出（程式範例接 D7）
● AO：類比訊號輸出（接 A0）
#include "SSD1306.h" //匯入OLED程式庫
SSD1306 display(0x3C, D2, D1); //宣告使用OLED螢幕物件(位址,SDA,SCL）==SDA>D2,SCL>D1
#define gas_Pin D7 // 設定煙霧/可燃氣感測器的數位接腳 D7 or 13
int gas_value;
String message;
long previousTime = 0; // 用來保存前一次狀態的時間
long interval = 1000; // 讀取間隔時間，單位為毫秒(miliseconds)
void setup(){
display.init(); //螢幕初始化
display.flipScreenVertically(); //螢幕垂直翻轉
display.setFont(ArialMT_Plain_16); //使用16字體
display.setTextAlignment(TEXT_ALIGN_LEFT); //靠左對齊
pinMode(gas_Pin, INPUT); // 設定 gas_Pin 為輸入模式
}
void loop(){
unsigned long currentTime = millis(); //將當前的時間存入變數currentTime
if (currentTime - previousTime > interval) { //如果當前時間扣除前一次保留時間超過間隔時間(interval)就進入執行程式
gas_value = analogRead(A0); // 讀取類比腳位 A0 煙霧/可燃氣的感測數值
if (digitalRead(gas_Pin) == LOW){ // 可燃氣/煙霧感測值高於設定閾值時，數位輸出訊號為 LOW（0），顯示 Alarm
message = "Status : Alarm";
}
else { // 可燃氣/煙霧感測值低於設定閾值時，數位輸出訊號為 HIGH（1)，顯示 Safe
message = "Status : Safe";
}
previousTime = currentTime; // 離開if時更新時間
}
display.clear(); //清除螢幕
display.drawString(0, 0, message); //x=0,y=0 位置顯示可燃氣/煙霧的偵測狀態
display.drawString(0, 16, "Value : " + String(gas_value)); //x=0,y=16 位置顯示可燃氣/煙霧的數值 0~1023，數值越大，可燃氣/煙霧濃度愈高
display.display();//螢幕顯示畫面
}
氣體類的傳感器種類很多，包括：
MQ-2：煙霧氣體（液化氣 / 丙烷 / 氫氣）感測器模組
MQ-3：酒精感測器模組
MQ-4：天然氣、甲烷感測器模組
MQ-5：液化氣、天然氣、瓦斯氣體感測器
MQ-6：丙烷、液化氣氣體感測器模組模組
MQ-7：一氧化碳感測模組
MQ-8：氫氣氣體感測器模組空氣檢測模組
MQ-9：一氧化碳 / 甲烷 / 液化氣可燃氣體感測器模組
MQ-131：HO3 臭氧氣體感測模組臭氧傳感器模組
MQ-135：空汙檢測（氨 / 苯 / 酒精）有害氣體感測器模組
MQ-136：硫化氫液化氣煙霧感測器模組
MQ-137：氣體 Ammonia 阿摩尼亞 NH3 氨氣檢測模組
MQ-138：甲醛偵測感測器模組甲醛酮醇類氣體傳感器模組
MQ-139：氟利昂（氟氯烷）檢測感測器氣體檢測模組
MQ-214：甲烷感測器 可燃氣感測器模組
