#include "SSD1306.h" //匯入OLED程式庫

#include "Multichannel_Gas_GMXXX.h"

#include "Wire.h"

SSD1306  display(0x3C, D2, D1);    //宣告使用OLED螢幕物件(位址,SDA,SCL）==SDA>D2,SCL>D1

GAS_GMXXX< TwoWire > gas;

int NO2_value, C2H5CH_value, VOC_value, CO_value;

long previousTime = 0;          // 用來保存前一次狀態的時間

long interval = 2000;           // 讀取間隔時間，單位為毫秒(miliseconds)

 

void setup() {

  display.init(); //螢幕初始化

  display.flipScreenVertically();  //螢幕垂直翻轉

  display.setFont(ArialMT_Plain_16);    //使用16字體

  display.setTextAlignment(TEXT_ALIGN_LEFT);  //靠左對齊

  gas.begin(Wire, 0x08); // use the hardware I2C

}

 

void loop() {

  unsigned long currentTime = millis();  //將當前的時間存入變數currentTime

  if(currentTime - previousTime > interval) {  //如果當前時間扣除前一次保留時間超過間隔時間(interval)就進入執行程式

     // GM102B NO2 sensor

     NO2_value = gas.getGM102B();

     if (NO2_value > 999) NO2_value = 999;

 

     // GM302B C2H5CH sensor

     C2H5CH_value = gas.getGM302B();

     if (C2H5CH_value > 999) C2H5CH_value = 999;

 

     // GM502B VOC sensor

     VOC_value = gas.getGM502B();

     if (VOC_value > 999) VOC_value = 999;

 

     // GM702B CO sensor

     CO_value = gas.getGM702B();

     if (CO_value > 999) CO_value = 999;

     

     previousTime = currentTime;  // 離開if時更新時間

  }

 

  display.clear();  //清除螢幕

  display.drawString(0, 0, "NO2:"+String(NO2_value)+"ppm"); //x=0,y=0位置顯示二氧化氮（NO2）的值

  display.drawString(0, 16, "C2H5CH:"+String(C2H5CH_value)+"ppm"); //x=0,y=16位置顯示乙醇（C2H5CH）的值

  display.drawString(0, 32, "VOC:"+String(VOC_value)+"ppm"); //x=0,y=32位置顯示揮發性有機化合物（VOC） 的值

  display.drawString(0, 48, "CO:"+String(CO_value)+"ppm"); //x=0,y=48位置顯示一氧化碳（CO）的值

  display.display();  //OLED螢幕顯示畫面

}